Orange Trees: Non-linear growth
         curve

This dataset was originally presented by Draper and Smith (1981) and reanalysed by Lindstrom and Bates (1990). The data Y _ij consist of trunk circumference measurements recorded at time x _j , j=1,...,7 for each of i = 1,..., 5 orange trees. We consider a logistic growth curve as follows:

   Y _ij    ~   Normal( h _ij , t _c )
   
    h _ij     =       f _i1
            _______________
            1 + f _i2 exp( f _i3 x _j )
            
    q _i1     =   log( f _i1 )    
    q _i2     =   log( f _i2 + 1)    
    q _i3     =   log( -f _i3 )    

The BUGS code is as follows

   model {
      for (i in 1:K) {
         for (j in 1:n) {
            Y[i, j] ~ dnorm(eta[i, j], tauC)
            eta[i, j] <- phi[i, 1] / (1 + phi[i, 2] * exp(phi[i, 3] * x[j]))
         }
         phi[i, 1] <- exp(theta[i, 1])
         phi[i, 2] <- exp(theta[i, 2]) - 1
         phi[i, 3] <- -exp(theta[i, 3])
         for (k in 1:3) {
            theta[i, k] ~ dnorm(mu[k], tau[k])
         }
      }
      tauC ~ dgamma(1.0E-3, 1.0E-3)
      sigma.C <- 1 / sqrt(tauC)
      var.C <- 1 / tauC
      for (k in 1:3) {
         mu[k] ~ dnorm(0, 1.0E-4)
         tau[k] ~ dgamma(1.0E-3, 1.0E-3)
         sigma[k] <- 1 / sqrt(tau[k])
      }
   }

Data ( click to open )

Inits for chain 1       Inits for chain 2    ( click to open )


Results

The hybrid Metropolis algorithm is used to sample the theta parameters in this model. The step length used for this algorithm adapts for the first 4000 iterations and these samples are discarded from the summary statistics. A further 1000 update burn-in followed by 10000 updates gave the following parameter estimates: